[ Foro de Pseudocódigo ]

Pseint flexible - Encuesta sobre bebidas

07-Jul-2020 04:17
Invitado (Martin )
2 Respuestas

Buenas noches requiero comedidamente de su ayuda. Se le agradece por mil
Realizar un algoritmo que permita realizar una encuesta sobre bebidas
A un grupo de 50 peesonas y debe mostrar 3 opcio es
Pepsi
Gallito
Fioravanti
Cada persona que se le haga la encuesta debeea elegir
Por una de las opciones, debiendo contabilizar por la bebida escogida
, en caso de que halla ingresado una respuesta diferente, debera
Solicitarse nuevamente la respuesta  hasta que se válida. Al final deberá
Mostrar el nombre de las 3 bebidas y cual fue la de mayor preferencia.


07-Jul-2020 17:24
Jorge Mina



Algoritmo Encuesta
	// Delcaramos las variables a utilizar
	Definir  nPepsi , nGatillo, nFioravanti, seleccion Como Entero
	Definir validar Como Logico
	// usamos una estructua 'Para' solicitar las 50 votaciones
	Para i <- 1 Hasta 50 Con Paso 1 Hacer
		Imprimir  "¡Buenos dias persona #", i, " le invitamos a que seleccione su bebida favorita"
		Imprimir  "Presione: 1 para Pepsi"
		Imprimir  "Presione: 2 para Gatillo"
		Imprimir  "Presione: 3 para Fioravanti"
		// Para evitar que se ingrese una entrada invalida usamos Repetir
		Repetir
			validar <- Falso
			Leer seleccion
			// usamos un Segun  para cada uno de las diferentes opciones
			Segun seleccion Hacer
				1:
					Imprimir  "Ha seleccionado Pepsi, gracias por su Colaboracion"
					nPepsi <- nPepsi + 1
					validar <- Verdadero
				2:
					Imprimir  "Ha seleccionado Gatillo, gracias por su Colaboracion"
					nGatillo <- nGatillo + 1
					validar <- Verdadero
				3:
					Imprimir  "Ha seleccionado Fioravanti, gracias por su Colaboracion"
					nFioravanti <- nFioravanti + 1
					validar <- Verdadero
				De Otro Modo:
					Imprimir  "Ha ingresado una Entrada Invalida, por favor"
					Imprimir  "Presione: 1 para Pepsi"
					Imprimir  "Presione: 2 para Gatillo"
					Imprimir  "Presione: 3 para Fioravanti"
					validar <- Falso
			Fin Segun
		Hasta Que validar
	Fin Para
	// Ahora procedemos a imprimir los resultados
	Imprimir "Las votaciones han concluido con los siguientes resultados: "
	Imprimir "Para Pepsi un total de "  nPepsi " votos"
	Imprimir "Para Gatillo un total de "  nGatillo " votos"
	Imprimir "Para Frioravanti un total de "  nFioravanti " votos"
	// y ahora imprimimos a el ganador usando una estructura SI-Entonces
	Si nPepsi > nGatillo & nPepsi > nFioravanti Entonces
		Imprimir "Pepsi es la bebida mas popular"
	SiNo
		Si nGatillo > nFioravanti Entonces
			Imprimir "Gatillo es la bebida mas popular"
		SiNo
			 Imprimir "Fioravanti es la bebida mas popular"
		Fin Si
	Fin Si
FinAlgoritmo


Ahi esta espero que sea la respuesta que buscas o al menos te de una idea de que camino seguir

PD:  eso si te dejo de tarea que hacen caso de empate.


09-Jul-2020 19:24
Invitado (Martin Pibaque )

Buenas tarde, quiero agradecerte Jorge Mina por tu gran ayuda te lo agradezco que hallas respondido y haber dado con la solución de este ejercicio. Mil gracias ingeniero
Saludos.






(No se puede continuar esta discusión porque tiene más de dos meses de antigüedad. Si tienes dudas parecidas, abre un nuevo hilo.)